Version bump

(Portage version: 2.1.11.9/cvs/Linux x86_64)

2 files changed, 136 insertions, 1 deletions

diff --git a/dev-lang/swi-prolog/ChangeLog b/dev-lang/swi-prolog/ChangeLog
index 0fa7a6cf5ba8..2472cb8153ad 100644
--- a/dev-lang/swi-prolog/ChangeLog
+++ b/dev-lang/swi-prolog/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/swi-prolog
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.343 2012/08/31 14:33:30 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.344 2012/09/12 12:00:13 keri Exp $
+
+*swi-prolog-6.2.1 (12 Sep 2012)
+
+  12 Sep 2012; <keri@gentoo.org> +swi-prolog-6.2.1.ebuild:
+  Version bump
 
 *swi-prolog-6.3.0 (31 Aug 2012)
 
diff --git a/dev-lang/swi-prolog/swi-prolog-6.2.1.ebuild b/dev-lang/swi-prolog/swi-prolog-6.2.1.ebuild
new file mode 100644
index 000000000000..1d9d7ce4dd5d
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-6.2.1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/swi-prolog-6.2.1.ebuild,v 1.1 2012/09/12 12:00:13 keri Exp $
+
+EAPI=2
+
+inherit eutils flag-o-matic java-pkg-opt-2 multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="free, small, and standard compliant Prolog compiler"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/stable/src/pl-${PV}.tar.gz
+	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="archive debug doc gmp hardened java minimal odbc readline ssl static-libs test zlib X"
+
+RDEPEND="sys-libs/ncurses
+	archive? ( app-arch/libarchive )
+	zlib? ( sys-libs/zlib )
+	odbc? ( dev-db/unixODBC )
+	readline? ( sys-libs/readline )
+	gmp? ( dev-libs/gmp )
+	ssl? ( dev-libs/openssl )
+	java? ( >=virtual/jdk-1.4 )
+	X? (
+		virtual/jpeg
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xproto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/pl-${PV}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	epatch "${WORKDIR}"/${PV}
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use ppc && append-flags -mno-altivec
+	use hardened && append-flags -fno-unit-at-a-time
+	use debug && append-flags -DO_DEBUG
+
+	cd "${S}"/src
+	econf \
+		--libdir=/usr/$(get_libdir) \
+		$(use_enable gmp) \
+		$(use_enable readline) \
+		$(use_enable static-libs static) \
+		--enable-shared \
+		--enable-custom-flags COFLAGS="${CFLAGS}"
+}
+
+src_compile() {
+	cd "${S}"/src
+	emake || die "emake failed"
+
+	if ! use minimal ; then
+		local jpltestconf
+		if use java && use test ; then
+			jpltestconf="--with-junit=$(java-config --classpath junit)"
+		fi
+
+		cd "${S}/packages"
+		econf \
+			--libdir=/usr/$(get_libdir) \
+			$(use_with archive) \
+			--with-chr \
+			--with-clib \
+			--with-clpqr \
+			--with-cpp \
+			--with-http \
+			$(use_with java jpl) \
+			${jpltestconf} \
+			--with-nlp \
+			$(use_with odbc) \
+			--with-PDT \
+			--with-pldoc \
+			--with-plunit \
+			--with-protobufs \
+			--with-R \
+			--with-RDF \
+			--with-semweb \
+			--with-sgml \
+			$(use_with ssl) \
+			--with-table \
+			--with-tipc \
+			--with-utf8proc \
+			$(use_with X xpce) \
+			$(use_with zlib) \
+			COFLAGS='"${CFLAGS}"'
+
+		emake || die "packages emake failed"
+	fi
+}
+
+src_test() {
+	cd "${S}/src"
+	emake check || die "make check failed. See above for details."
+
+	if ! use minimal ; then
+		cd "${S}/packages"
+		emake check || die "make check failed. See above for details."
+	fi
+}
+
+src_install() {
+	emake -C src DESTDIR="${D}" install || die "install src failed"
+
+	if ! use minimal ; then
+		emake -C packages DESTDIR="${D}" install || die "install packages failed"
+		if use doc ; then
+			emake -C packages DESTDIR="${D}" html-install || die "html-install failed"
+		fi
+	fi
+
+	dodoc ReleaseNotes/relnotes-5.10 INSTALL README VERSION || die
+}