Bump -6.3 development version

(Portage version: 2.1.11.9/cvs/Linux x86_64)

2 files changed, 131 insertions, 1 deletions

diff --git a/dev-lang/swi-prolog/ChangeLog b/dev-lang/swi-prolog/ChangeLog
index 9bc8b3d0c430..654cbbd9be75 100644
--- a/dev-lang/swi-prolog/ChangeLog
+++ b/dev-lang/swi-prolog/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/swi-prolog
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.358 2012/10/31 11:59:35 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/ChangeLog,v 1.359 2012/11/22 09:56:51 keri Exp $
+
+*swi-prolog-6.3.4 (22 Nov 2012)
+
+  22 Nov 2012; <keri@gentoo.org> +swi-prolog-6.3.4.ebuild:
+  Bump -6.3 development version
 
 *swi-prolog-6.3.3 (31 Oct 2012)
 
diff --git a/dev-lang/swi-prolog/swi-prolog-6.3.4.ebuild b/dev-lang/swi-prolog/swi-prolog-6.3.4.ebuild
new file mode 100644
index 000000000000..2245a7e6d234
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-6.3.4.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swi-prolog/swi-prolog-6.3.4.ebuild,v 1.1 2012/11/22 09:56:51 keri Exp $
+
+EAPI=4
+
+inherit eutils flag-o-matic java-pkg-opt-2 multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="free, small, and standard compliant Prolog compiler"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/pl-${PV}.tar.gz
+	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="archive debug doc gmp hardened java minimal odbc readline ssl static-libs test zlib X"
+
+RDEPEND="sys-libs/ncurses
+	archive? ( app-arch/libarchive )
+	zlib? ( sys-libs/zlib )
+	odbc? ( dev-db/unixODBC )
+	readline? ( sys-libs/readline )
+	gmp? ( dev-libs/gmp )
+	ssl? ( dev-libs/openssl )
+	java? ( >=virtual/jdk-1.4 )
+	X? (
+		virtual/jpeg
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-proto/xproto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/pl-${PV}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	epatch "${WORKDIR}"/${PV}
+
+	# OSX/Intel ld doesn't like an archive without table of contents
+	sed -i -e 's/-cru/-scru/' packages/nlp/libstemmer_c/Makefile.pl || die
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use ppc && append-flags -mno-altivec
+	use hardened && append-flags -fno-unit-at-a-time
+	use debug && append-flags -DO_DEBUG
+
+	# ARCH is used in the configure script to figure out host and target
+	# specific stuff
+	export ARCH=${CHOST}
+
+	export CC_FOR_BUILD=$(tc-getBUILD_CC)
+
+	cd "${S}"/src
+	econf \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		$(use_enable gmp) \
+		$(use_enable readline) \
+		$(use_enable static-libs static) \
+		--enable-shared \
+		--enable-custom-flags COFLAGS="${CFLAGS}"
+
+	if ! use minimal ; then
+		local jpltestconf
+		if use java && use test ; then
+			jpltestconf="--with-junit=$(java-config --classpath junit)"
+		fi
+
+		cd "${S}/packages"
+		econf \
+			--libdir="${EPREFIX}"/usr/$(get_libdir) \
+			$(use_with archive) \
+			$(use_with java jpl) \
+			${jpltestconf} \
+			$(use_with odbc) \
+			$(use_with ssl) \
+			$(use_with X xpce) \
+			$(use_with zlib) \
+			COFLAGS='"${CFLAGS}"'
+	fi
+}
+
+src_compile() {
+	cd "${S}"/src
+	emake
+
+	if ! use minimal ; then
+		cd "${S}/packages"
+		emake
+	fi
+}
+
+src_test() {
+	cd "${S}/src"
+	emake check
+
+	if ! use minimal ; then
+		cd "${S}/packages"
+		emake check
+	fi
+}
+
+src_install() {
+	emake -C src DESTDIR="${D}" install
+
+	if ! use minimal ; then
+		emake -C packages DESTDIR="${D}" install
+		if use doc ; then
+			emake -C packages DESTDIR="${D}" html-install
+		fi
+	fi
+
+	dodoc ReleaseNotes/relnotes-5.10 INSTALL README VERSION
+}