PDEPEND on relevant dictionaries according to LINGUAS

(Portage version: 2.1.2_rc2-r1)

2 files changed, 108 insertions, 0 deletions

diff --git a/app-text/aspell/aspell-0.60.4-r2.ebuild b/app-text/aspell/aspell-0.60.4-r2.ebuild
new file mode 100644
index 000000000000..4839e292845a
--- /dev/null
+++ b/app-text/aspell/aspell-0.60.4-r2.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/aspell/aspell-0.60.4-r2.ebuild,v 1.1 2006/12/01 09:56:12 kevquinn Exp $
+
+# N.B. This is before inherit of autotools, as autotools.eclass adds the
+# relevant dependencies to DEPEND.
+WANT_AUTOMAKE="1.9"
+
+inherit libtool eutils flag-o-matic autotools
+
+DESCRIPTION="A spell checker replacement for ispell"
+HOMEPAGE="http://aspell.net/"
+SRC_URI="mirror://gnu/aspell/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gpm nls"
+# Note; app-text/aspell-0.6 and app-dicts/aspell-en-0.6 must go stable together
+
+# Build PDEPEND from list of language codes provided in the tree.
+# The PDEPEND string is static - this code just makes it easier to maintain.
+def="app-dicts/aspell-en"
+for l in \
+	"af" "be" "bg" "br" "ca" "cs" "cy" "da" "de" "el" \
+	"en" "eo" "es" "et" "fi" "fo" "fr" "ga" "gl" "he" \
+	"hr" "is" "it" "nl" "no" "pl" "pt" "ro" "ru" "sk" \
+	"sl" "sr" "sv" "uk" "vi"; do
+	dep="linguas_${l}? ( app-dicts/aspell-${l} )"
+	[[ -z ${PDEPEND} ]] &&
+		PDEPEND="${dep}" ||
+		PDEPEND="${PDEPEND}
+${dep}"
+	def="!linguas_${l}? ( ${def} )"
+done
+PDEPEND="${PDEPEND}
+${def}"
+
+RDEPEND=">=sys-libs/ncurses-5.2
+	virtual/aspell-dict
+	gpm? ( sys-libs/gpm )
+	nls? ( virtual/libintl )
+	!=app-dicts/aspell-en-0.5*"
+# English dictionary 0.5 is incompatible with aspell-0.6
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/aspell-0.60.3-templateinstantiations.patch
+	epatch "${FILESDIR}"/aspell-0.60.4-gcc-4.1-fix.patch
+	epatch "${FILESDIR}/${P}-nls.patch"
+
+	eautomake
+	elibtoolize --reverse-deps
+}
+
+src_compile() {
+	use gpm && append-ldflags -lgpm
+	filter-flags -fno-rtti
+	filter-flags -fvisibility=hidden #77109
+	filter-flags -maltivec -mabi=altivec
+	use ppc && append-flags -mno-altivec
+
+	econf \
+		$(use_enable nls) \
+		--disable-static \
+		--sysconfdir=/etc/aspell \
+		--enable-docdir=/usr/share/doc/${PF} || die
+
+	emake || die
+}
+
+src_install() {
+	dodoc README* TODO
+
+	make DESTDIR="${D}" install || die
+	mv "${D}"/usr/share/doc/${PF}/man-html "${D}"/usr/share/doc/${PF}/html
+	mv "${D}"/usr/share/doc/${PF}/man-text "${D}"/usr/share/doc/${PF}/text
+
+	# install ispell/aspell compatibility scripts
+	exeinto /usr/bin
+	newexe scripts/ispell ispell-aspell
+	newexe scripts/spell spell-aspell
+
+	cd examples
+	make clean || die
+	docinto examples
+	dodoc ${S}/examples/*
+}
+
+pkg_postinst() {
+	einfo "You will need to install a dictionary now.  Please choose an"
+	einfo "aspell-<LANG> dictionary from the app-dicts category"
+	einfo "After installing an aspell dictionary for your language(s),"
+	einfo "You may use the aspell-import utility to import your personal"
+	einfo "dictionaries from ispell, pspell and the older aspell"
+
+	ewarn ""
+	ewarn "Please re-emerge ALL your aspell-LANG dictionaries"
+	ewarn ""
+	ebeep 5
+}
diff --git a/app-text/aspell/files/digest-aspell-0.60.4-r2 b/app-text/aspell/files/digest-aspell-0.60.4-r2
new file mode 100644
index 000000000000..b06cd5ec9fa6
--- /dev/null
+++ b/app-text/aspell/files/digest-aspell-0.60.4-r2
@@ -0,0 +1,3 @@
+MD5 4f1737e726d66476b9c7388831305510 aspell-0.60.4.tar.gz 1676825
+RMD160 e0408acd4f3304c957aeea0b17a28d0c44e11064 aspell-0.60.4.tar.gz 1676825
+SHA256 8931d8644da9a71fdd970cafe9d6c20d796ad1d8ef2aaf89a801171104e426e4 aspell-0.60.4.tar.gz 1676825