New alpha release. Be sure to test HTTP stream handling.

(Portage version: 2.1.2-r4)

3 files changed, 74 insertions, 1 deletions

diff --git a/media-sound/audacious/ChangeLog b/media-sound/audacious/ChangeLog
index 647c7205d039..ac774c43f920 100644
--- a/media-sound/audacious/ChangeLog
+++ b/media-sound/audacious/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.100 2007/01/08 00:32:40 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.101 2007/01/25 14:47:13 chainsaw Exp $
+
+*audacious-1.3.0_alpha3 (25 Jan 2007)
+
+  25 Jan 2007; Tony Vroon <chainsaw@gentoo.org>
+  +audacious-1.3.0_alpha3.ebuild:
+  New alpha release. Be sure to test HTTP stream handling.
 
 *audacious-1.3.0_alpha2 (08 Jan 2007)
 
diff --git a/media-sound/audacious/audacious-1.3.0_alpha3.ebuild b/media-sound/audacious/audacious-1.3.0_alpha3.ebuild
new file mode 100644
index 000000000000..5125e3cc1852
--- /dev/null
+++ b/media-sound/audacious/audacious-1.3.0_alpha3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-1.3.0_alpha3.ebuild,v 1.1 2007/01/25 14:47:14 chainsaw Exp $
+
+inherit flag-o-matic
+
+MY_P=${P/_/-}
+S=${WORKDIR}/${MY_P}
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://static.audacious-media-player.org/release/${MY_P}.tgz
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="chardet nls gnome"
+
+RDEPEND=">=x11-libs/gtk+-2.6
+	>=gnome-base/libglade-2.3.1
+	dev-libs/libxml2
+	gnome? ( >=gnome-base/gconf-2.6.0 )"
+
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	>=dev-util/pkgconfig-0.9.0"
+
+PDEPEND=">=media-plugins/audacious-plugins-1.3.0_alpha3"
+
+src_compile() {
+	# Bug #42893
+	replace-flags "-Os" "-O2"
+	# Bug #86689
+	is-flag "-O*" || append-flags -O
+
+	econf \
+		$(use_enable chardet) \
+		$(use_enable nls) \
+		$(use_enable gnome gconf) \
+		|| die
+
+	emake || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc AUTHORS NEWS README
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}
+
+pkg_postinst() {
+	ewarn "This is alpha-quality software, and you have unmasked this software manually. Do *not* use the Gentoo bugtracker for this package."
+	elog "Note that you need to recompile *all* third-party plugins to use Audacious 1.3 alpha builds."
+	elog "Failure to do so may cause the player to crash."
+	elog "Any bug reports are to be made on: http://bugs-meta.atheme.org/"
+}
diff --git a/media-sound/audacious/files/digest-audacious-1.3.0_alpha3 b/media-sound/audacious/files/digest-audacious-1.3.0_alpha3
new file mode 100644
index 000000000000..0e9c2480f4e2
--- /dev/null
+++ b/media-sound/audacious/files/digest-audacious-1.3.0_alpha3
@@ -0,0 +1,6 @@
+MD5 7b96469db6795219dc62473d3de6c6c1 audacious-1.3.0-alpha3.tgz 1673324
+RMD160 bc62314bd520f850cfffbba061270905b3fb3ccf audacious-1.3.0-alpha3.tgz 1673324
+SHA256 8bf6df7fde34ff71f9944685c1739f556990341c8fa3ff55f455a5a6ee1da502 audacious-1.3.0-alpha3.tgz 1673324
+MD5 41eababfa8bad11e9e34e467cdfb86be gentoo_ice-xmms-0.2.tar.bz2 51839
+RMD160 11439cbebf8c6dc5745c8593a79e88303d094544 gentoo_ice-xmms-0.2.tar.bz2 51839
+SHA256 d1be63368b76f4a8b1d5b0e955cd7a77177f56a7f0b828c6603d8fd2836422b1 gentoo_ice-xmms-0.2.tar.bz2 51839